home *** CD-ROM | disk | FTP | other *** search
/ Ham Radio 2000 #2 / Ham Radio 2000 - Volume 2.iso / HAMV2 / MISC / HCAL-27 / HCAL.BAS (.txt) < prev    next >
Encoding:
GW-BASIC  |  1997-03-25  |  2.5 KB  |  88 lines
  1. 10  'HCAL - HAMCALC Main menu - 03 JUN 94 - rev. 25 MAR 97
  2. 20  CLS:KEY OFF
  3. 30  COMMON EX$
  4. 40  KEY 10,"SYSTEM"+CHR$(13)
  5. 50  EX$="\bas\menu\hcal"
  6. 60  '.....see STRAYS, Oct.1993 QST, page 23
  7. 70  V$="27 "                'version
  8. 80  D$="  25 MAR 97  "      'date of latest version
  9. 90  COLOR 15,0,7
  10. 100  U$=STRING$(80,205)
  11. 110  DIM A$(19),B$(19),C$(19)
  12. 120  ON ERROR GOTO 350
  13. 130  COLOR 14,1
  14. 140  PRINT "    H  A  M  C  A  L  C    ";
  15. 150  COLOR 1,7
  16. 160  PRINT "  Version ";V$;D$;
  17. 170  COLOR 14,1
  18. 180  PRINT TAB(56);"by George Murphy VE3ERP  ";
  19. 190  COLOR 7,1:PRINT STRING$(80,223);
  20. 200  COLOR 14,1
  21. 210  VIEW PRINT 3 TO 24:CLS:VIEW PRINT:LOCATE 3   'set screen background color
  22. 220  COLOR 14,1
  23. 230  LOCATE ,24:PRINT " PAINLESS MATH for RADIO AMATEURS "
  24. 240  COLOR 14,4
  25. 250  LOCATE ,32:PRINT " M A I N   M E N U "
  26. 260  COLOR 7,1:PRINT STRING$(80,220);
  27. 270  PRINT
  28. 280  COLOR 15,1:PRINT " Turn your";
  29. 290  COLOR 15,1:PRINT " Caps Lock OFF ";
  30. 300  COLOR 15,1
  31. 310  PRINT "then press any letter in ( ) to select:"
  32. 320  PRINT U$;
  33. 330  N=0:GOTO 370
  34. 340  '
  35. 350  PRINT "Error ";ERR;" in line ";ERL:END
  36. 360  '
  37. 370  NM=15   'number of menu items
  38. 380  FOR N=1 TO NM:A$(N)=CHR$(N+96)
  39. 390  IF N=6 THEN COLOR 14,4
  40. 400  IF N=7 THEN COLOR 15,1
  41. 410  READ B$(N),C$(N)
  42. 420  LOCATE CSRLIN,24:PRINT "(";A$(N);")  ";C$(N);" "
  43. 430  NEXT N
  44. 440  COLOR 7:LOCATE 24:PRINT STRING$(80,220);
  45. 450  COLOR 14,1:LOCATE 25:PRINT "   ";CHR$(34);
  46. 460  PRINT "Aversion to mathematics is not an acquired distaste - ";
  47. 470  PRINT "it comes naturally";CHR$(34);"   ";
  48. 480  COLOR 7,0
  49. 490  Z$=INKEY$:IF Z$=""THEN 490
  50. 500  FOR Z=1 TO NM
  51. 510  IF ASC(Z$)>=65 AND ASC(Z$)<=80 THEN 600
  52. 520  IF Z$=A$(Z)THEN 560
  53. 530  NEXT Z
  54. 540  GOTO 490
  55. 550  '
  56. 560  IF B$(Z)=""THEN 490
  57. 570  CLS:CHDIR"\bas\prog"
  58. 580  COLOR 7,0,1:CHAIN B$(Z)
  59. 590  '
  60. 600  '.....caps lock warning
  61. 610  CLS:BEEP:COLOR 14,4
  62. 620  PRINT
  63. 630  PRINT " Please turn your CAPS LOCK off and make all entries in lower case ";
  64. 640  PRINT " characters only."
  65. 650  PRINT
  66. 660  PRINT " The computer will provide upper case characters where appropriate."
  67. 670  PRINT
  68. 680  PRINT " Turn CAPS LOCK off NOW then press any key to continue............."
  69. 690  IF INKEY$=""THEN 690
  70. 700  CLS:CLEAR:COLOR 7,0,0:GOTO 10
  71. 710  '
  72. 720  DATA \bas\menu\hcal-a,Program Menu A  ( 555 Timer - Crystal )
  73. 730  DATA \bas\menu\hcal-b,Program Menu B  ( Decibel - Maximum )
  74. 740  DATA \bas\menu\hcal-c,Program Menu C  ( Meteor - Short )
  75. 750  DATA \bas\menu\hcal-d,Program Menu D  ( Single - Yagi )
  76. 760  DATA \bas\menu\hcal-e,Program Menu E  ( Yagi - Zepp )
  77. 770  DATA \bas\prog\hamdex,INDEX
  78. 780  DATA \bas\prog\helphint,HELPFUL HINTS
  79. 790  DATA \bas\prog\lptsetup,PRINTER SETUP
  80. 800  DATA \bas\prog\sunclock,Screen Saver Clock
  81. 810  DATA \bas\prog\cpyhcal,COPY HAMCALC to a disk or INSTALL on a Hard Drive
  82. 820  DATA \bas\prog\newsince,HISTORY of recent program additions & upgrades
  83. 830  DATA \bas\prog\uninstal,Remove HAMCALC from a Hard Drive
  84. 840  DATA \bas\prog\tree,VIEW Directory Structure
  85. 850  DATA "",-
  86. 860  DATA \bas\prog\zexit,EXIT to DOS
  87. 870  END
  88.